; wp\_gseSTS1D

; W. S. Price 14 August 2006

; 1D Hahn spin echo with gradients for diffusion measurements

; This sequence contains a purge gradient/steady state gradient

; prepulse(s) before the pi/2 pulse.

; Check that SWEEP is off !!!

; Check that (c:\Bruker\xwin-nmr\exp\stan\nmr\list\gp\cag\_par) is

; 1.0

; 1.0

; 1.0

; 1.0 0.0 0.0

; 0.0 1.0 0.0

; 0.0 0.0 1.0

#include <Avance.incl>

#include <Grad.incl>

"p2=p1 \* 2.0"

"d22=50u"

"d29=(d15 - d22 - d22 - p16 - d17 - p2)/2"

"d30=d29 - p1"

"d31=p2"

define loopcounter nPrepul

"nPrepul=1"

1 ze

2 d1

Prepulse, d29

d22 UNBLKGRAD

p17:gp2

d17

d22 BLKGRAD

d29

d31

lo to Prepulse times nPrepul

d30

p1 ph1

d22 UNBLKGRAD

p16:gp1

d17

d22 BLKGRAMP

d29

p2 ph2

d29

d22 UNBLKGRAMP

p16:gp1

d17

d22 BLKGRAD

go=2 ph31

wr #0

exit

ph1 = 0 2

ph2 = 0 2 1 3 2 0 3 1

ph31 = 0 2 2 0

;RF PULSES

;pl1 : f1 channel - power level for pulse (default)

;p1 : f1 channel - 90 degree high power pulse

;p2 : f1 channel - 180 degree high power pulse, it is calculated from p1

;DELAYS

;d1 : relaxation delay; 1-5 \* T1

;d15 : Capital Delta

;d17 gradient recovery delay (~ 100 us should be enough for high res probe)

;GRADIENTS

;p16: diffusion gradient pulse = little delta [1-5 ms]

; gradient shape is controlled by gpnam1 (e.g., wp\_squa50)

; gradient amplitude is controlled by gpz1 (in %)

;p17: purge/steady gradient prepulse = little delta [1-5 ms]

; gradient shape is controlled by gpnam2 (e.g., wp\_squa50)

; gradient amplitude is controlled by gpz2 (in %)

; use something like 40% (on a 10 A amp with HR probe)

;SCANS AND PHASE CYCLES

;NS: preferably 8 \* n

;DS: use a sufficient number so as to reach steady state magnetization.

;use the au program wp\_diffamp to increment the gradients